vendor/llvm/llvm-release_39-r276489

4 files changed, 300 insertions, 3 deletions

diff --git a/test/Transforms/EarlyCSE/basic.ll b/test/Transforms/EarlyCSE/basic.ll
index 8c9b74b4d0e1d..fa1a7059db955 100644
--- a/test/Transforms/EarlyCSE/basic.ll
+++ b/test/Transforms/EarlyCSE/basic.ll
@@ -26,10 +26,9 @@ define void @test1(i8 %V, i32 *%P) {
   ; CHECK-NEXT: store volatile i32 %E
   ; CHECK-NEXT: store volatile i32 %E
 
-  %G = add nuw i32 %C, %C         ;; not a CSE with E
+  %G = add nuw i32 %C, %C
   store volatile i32 %G, i32* %P
-  ; CHECK-NEXT: %G = add nuw i32 %C, %C
-  ; CHECK-NEXT: store volatile i32 %G
+  ; CHECK-NEXT: store volatile i32 %E
   ret void
 }
 
diff --git a/test/Transforms/EarlyCSE/flags.ll b/test/Transforms/EarlyCSE/flags.ll
new file mode 100644
index 0000000000000..d189012e4be8e
--- /dev/null
+++ b/test/Transforms/EarlyCSE/flags.ll
@@ -0,0 +1,18 @@
+; RUN: opt -early-cse -S < %s | FileCheck %s
+
+declare void @use(i1)
+
+define void @test1(float %x, float %y) {
+entry:
+  %cmp1 = fcmp nnan oeq float %y, %x
+  %cmp2 = fcmp oeq float %x, %y
+  call void @use(i1 %cmp1)
+  call void @use(i1 %cmp2)
+  ret void
+}
+
+; CHECK-LABEL: define void @test1(
+; CHECK: %[[cmp:.*]] = fcmp oeq float %y, %x
+; CHECK-NEXT: call void @use(i1 %[[cmp]])
+; CHECK-NEXT: call void @use(i1 %[[cmp]])
+; CHECK-NEXT: ret void
diff --git a/test/Transforms/EarlyCSE/guards.ll b/test/Transforms/EarlyCSE/guards.ll
new file mode 100644
index 0000000000000..2cc4753969b58
--- /dev/null
+++ b/test/Transforms/EarlyCSE/guards.ll
@@ -0,0 +1,181 @@
+; RUN: opt -S -early-cse < %s | FileCheck %s
+
+declare void @llvm.experimental.guard(i1,...)
+
+define i32 @test0(i32* %ptr, i1 %cond) {
+; We can do store to load forwarding over a guard, since it does not
+; clobber memory
+
+; CHECK-LABEL: @test0(
+; CHECK-NEXT:  store i32 40, i32* %ptr
+; CHECK-NEXT:  call void (i1, ...) @llvm.experimental.guard(i1 %cond) [ "deopt"() ]
+; CHECK-NEXT:  ret i32 40
+
+  store i32 40, i32* %ptr
+  call void(i1,...) @llvm.experimental.guard(i1 %cond) [ "deopt"() ]
+  %rval = load i32, i32* %ptr
+  ret i32 %rval
+}
+
+define i32 @test1(i32* %val, i1 %cond) {
+; We can CSE loads over a guard, since it does not clobber memory
+
+; CHECK-LABEL: @test1(
+; CHECK-NEXT:  %val0 = load i32, i32* %val
+; CHECK-NEXT:  call void (i1, ...) @llvm.experimental.guard(i1 %cond) [ "deopt"() ]
+; CHECK-NEXT:  ret i32 0
+
+  %val0 = load i32, i32* %val
+  call void(i1,...) @llvm.experimental.guard(i1 %cond) [ "deopt"() ]
+  %val1 = load i32, i32* %val
+  %rval = sub i32 %val0, %val1
+  ret i32 %rval
+}
+
+define i32 @test2() {
+; Guards on "true" get removed
+
+; CHECK-LABEL: @test2(
+; CHECK-NEXT: ret i32 0
+  call void(i1, ...) @llvm.experimental.guard(i1 true) [ "deopt"() ]
+  ret i32 0
+}
+
+define i32 @test3(i32 %val) {
+; After a guard has executed the condition it was guarding is known to
+; be true.
+
+; CHECK-LABEL: @test3(
+; CHECK-NEXT:  %cond0 = icmp slt i32 %val, 40
+; CHECK-NEXT:  call void (i1, ...) @llvm.experimental.guard(i1 %cond0) [ "deopt"() ]
+; CHECK-NEXT:  ret i32 -1
+
+  %cond0 = icmp slt i32 %val, 40
+  call void(i1,...) @llvm.experimental.guard(i1 %cond0) [ "deopt"() ]
+  %cond1 = icmp slt i32 %val, 40
+  call void(i1,...) @llvm.experimental.guard(i1 %cond1) [ "deopt"() ]
+
+  %cond2 = icmp slt i32 %val, 40
+  %rval = sext i1 %cond2 to i32
+  ret i32 %rval
+}
+
+define i32 @test3.unhandled(i32 %val) {
+; After a guard has executed the condition it was guarding is known to
+; be true.
+
+; CHECK-LABEL: @test3.unhandled(
+; CHECK-NEXT:  %cond0 = icmp slt i32 %val, 40
+; CHECK-NEXT:  call void (i1, ...) @llvm.experimental.guard(i1 %cond0) [ "deopt"() ]
+; CHECK-NEXT:  %cond1 = icmp sge i32 %val, 40
+; CHECK-NEXT:  call void (i1, ...) @llvm.experimental.guard(i1 %cond1) [ "deopt"() ]
+; CHECK-NEXT:  ret i32 0
+
+; Demonstrates a case we do not yet handle (it is legal to fold %cond2
+; to false)
+  %cond0 = icmp slt i32 %val, 40
+  call void(i1,...) @llvm.experimental.guard(i1 %cond0) [ "deopt"() ]
+  %cond1 = icmp sge i32 %val, 40
+  call void(i1,...) @llvm.experimental.guard(i1 %cond1) [ "deopt"() ]
+  ret i32 0
+}
+
+define i32 @test4(i32 %val, i1 %c) {
+; Same as test3, but with some control flow involved.
+
+; CHECK-LABEL: @test4(
+; CHECK: entry:
+; CHECK-NEXT:  %cond0 = icmp slt i32 %val, 40
+; CHECK-NEXT:  call void (i1, ...) @llvm.experimental.guard(i1 %cond0
+; CHECK-NEXT:  br label %bb0
+
+; CHECK:     bb0:
+; CHECK-NEXT:  %cond2 = icmp ult i32 %val, 200
+; CHECK-NEXT:  call void (i1, ...) @llvm.experimental.guard(i1 %cond2
+; CHECK-NEXT:  br i1 %c, label %left, label %right
+
+; CHECK:     left:
+; CHECK-NEXT:  ret i32 0
+
+; CHECK:     right:
+; CHECK-NEXT:  ret i32 20
+
+entry:
+  %cond0 = icmp slt i32 %val, 40
+  call void(i1,...) @llvm.experimental.guard(i1 %cond0) [ "deopt"() ]
+  %cond1 = icmp slt i32 %val, 40
+  call void(i1,...) @llvm.experimental.guard(i1 %cond1) [ "deopt"() ]
+  br label %bb0
+
+bb0:
+  %cond2 = icmp ult i32 %val, 200
+  call void(i1,...) @llvm.experimental.guard(i1 %cond2) [ "deopt"() ]
+  br i1 %c, label %left, label %right
+
+left:
+  %cond3 = icmp ult i32 %val, 200
+  call void(i1,...) @llvm.experimental.guard(i1 %cond3) [ "deopt"() ]
+  ret i32 0
+
+right:
+ ret i32 20
+}
+
+define i32 @test5(i32 %val, i1 %c) {
+; Same as test4, but the %left block has mutliple predecessors.
+
+; CHECK-LABEL: @test5(
+
+; CHECK: entry:
+; CHECK-NEXT:  %cond0 = icmp slt i32 %val, 40
+; CHECK-NEXT:  call void (i1, ...) @llvm.experimental.guard(i1 %cond0
+; CHECK-NEXT:  br label %bb0
+
+; CHECK: bb0:
+; CHECK-NEXT:  %cond2 = icmp ult i32 %val, 200
+; CHECK-NEXT:  call void (i1, ...) @llvm.experimental.guard(i1 %cond2
+; CHECK-NEXT:  br i1 %c, label %left, label %right
+
+; CHECK: left:
+; CHECK-NEXT:  br label %right
+
+; CHECK: right:
+; CHECK-NEXT:  br label %left
+
+entry:
+  %cond0 = icmp slt i32 %val, 40
+  call void(i1,...) @llvm.experimental.guard(i1 %cond0) [ "deopt"() ]
+  %cond1 = icmp slt i32 %val, 40
+  call void(i1,...) @llvm.experimental.guard(i1 %cond1) [ "deopt"() ]
+  br label %bb0
+
+bb0:
+  %cond2 = icmp ult i32 %val, 200
+  call void(i1,...) @llvm.experimental.guard(i1 %cond2) [ "deopt"() ]
+  br i1 %c, label %left, label %right
+
+left:
+  %cond3 = icmp ult i32 %val, 200
+  call void(i1,...) @llvm.experimental.guard(i1 %cond3) [ "deopt"() ]
+  br label %right
+
+right:
+  br label %left
+}
+
+define void @test6(i1 %c, i32* %ptr) {
+; Check that we do not DSE over calls to @llvm.experimental.guard.
+; Guard intrinsics do _read_ memory, so th call to guard below needs
+; to see the store of 500 to %ptr
+
+; CHECK-LABEL: @test6(
+; CHECK-NEXT:  store i32 500, i32* %ptr
+; CHECK-NEXT:  call void (i1, ...) @llvm.experimental.guard(i1 %c) [ "deopt"() ]
+; CHECK-NEXT:  store i32 600, i32* %ptr
+
+
+  store i32 500, i32* %ptr
+  call void(i1,...) @llvm.experimental.guard(i1 %c) [ "deopt"() ]
+  store i32 600, i32* %ptr
+  ret void
+}
diff --git a/test/Transforms/EarlyCSE/invariant-loads.ll b/test/Transforms/EarlyCSE/invariant-loads.ll
new file mode 100644
index 0000000000000..04c7dd1372d94
--- /dev/null
+++ b/test/Transforms/EarlyCSE/invariant-loads.ll
@@ -0,0 +1,99 @@
+; RUN: opt -S -early-cse < %s | FileCheck %s
+
+declare void @clobber_and_use(i32)
+
+define void @f_0(i32* %ptr) {
+; CHECK-LABEL: @f_0(
+; CHECK:   %val0 = load i32, i32* %ptr, !invariant.load !0
+; CHECK:   call void @clobber_and_use(i32 %val0)
+; CHECK:   call void @clobber_and_use(i32 %val0)
+; CHECK:   call void @clobber_and_use(i32 %val0)
+; CHECK:   ret void
+
+  %val0 = load i32, i32* %ptr, !invariant.load !{}
+  call void @clobber_and_use(i32 %val0)
+  %val1 = load i32, i32* %ptr, !invariant.load !{}
+  call void @clobber_and_use(i32 %val1)
+  %val2 = load i32, i32* %ptr, !invariant.load !{}
+  call void @clobber_and_use(i32 %val2)
+  ret void
+}
+
+define void @f_1(i32* %ptr) {
+; We can forward invariant loads to non-invariant loads, since once an
+; invariant load has executed, the location loaded from is known to be
+; unchanging.
+
+; CHECK-LABEL: @f_1(
+; CHECK:   %val0 = load i32, i32* %ptr, !invariant.load !0
+; CHECK:   call void @clobber_and_use(i32 %val0)
+; CHECK:   call void @clobber_and_use(i32 %val0)
+
+  %val0 = load i32, i32* %ptr, !invariant.load !{}
+  call void @clobber_and_use(i32 %val0)
+  %val1 = load i32, i32* %ptr
+  call void @clobber_and_use(i32 %val1)
+  ret void
+}
+
+define void @f_2(i32* %ptr) {
+; Negative test -- we can't forward a non-invariant load into an
+; invariant load.
+
+; CHECK-LABEL: @f_2(
+; CHECK:   %val0 = load i32, i32* %ptr
+; CHECK:   call void @clobber_and_use(i32 %val0)
+; CHECK:   %val1 = load i32, i32* %ptr, !invariant.load !0
+; CHECK:   call void @clobber_and_use(i32 %val1)
+
+  %val0 = load i32, i32* %ptr
+  call void @clobber_and_use(i32 %val0)
+  %val1 = load i32, i32* %ptr, !invariant.load !{}
+  call void @clobber_and_use(i32 %val1)
+  ret void
+}
+
+define void @f_3(i1 %cond, i32* %ptr) {
+; CHECK-LABEL: @f_3(
+  %val0 = load i32, i32* %ptr, !invariant.load !{}
+  call void @clobber_and_use(i32 %val0)
+  br i1 %cond, label %left, label %right
+
+; CHECK:  %val0 = load i32, i32* %ptr, !invariant.load !0
+; CHECK: left:
+; CHECK-NEXT:  call void @clobber_and_use(i32 %val0)
+
+left:
+  %val1 = load i32, i32* %ptr
+  call void @clobber_and_use(i32 %val1)
+  ret void
+
+right:
+  ret void
+}
+
+define void @f_4(i1 %cond, i32* %ptr) {
+; Negative test -- can't forward %val0 to %va1 because that'll break
+; def-dominates-use.
+
+; CHECK-LABEL: @f_4(
+  br i1 %cond, label %left, label %merge
+
+left:
+; CHECK: left:
+; CHECK-NEXT:  %val0 = load i32, i32* %ptr, !invariant.load !
+; CHECK-NEXT:  call void @clobber_and_use(i32 %val0)
+
+  %val0 = load i32, i32* %ptr, !invariant.load !{}
+  call void @clobber_and_use(i32 %val0)
+  br label %merge
+
+merge:
+; CHECK: merge:
+; CHECK-NEXT:   %val1 = load i32, i32* %ptr
+; CHECK-NEXT:   call void @clobber_and_use(i32 %val1)
+
+  %val1 = load i32, i32* %ptr
+  call void @clobber_and_use(i32 %val1)
+  ret void
+}